サクラエディタで行指向のgrep置換マクロ

サクラエディタで行指向のgrep置換マクロを作成。

行指向のgrep置換というのは、grepした結果を行単位で反映する置換の方法。

単純な単語置換や正規表現の置換ではできない置換ができる。

例えば、見出しで番号を振っているテキストファイルの場合、連番が間違っていることは正規表現「^\d」でgrepするとわかりやすい。

test.txt(3,1): 1. 見出し
test.txt(5,1): 1.2. 見出し
test.txt(7,1): 1.2. 見出し
test.txt(10,1): 2. 見出し
test.txt(12,1): 2.1. 見出し
test.txt(14,1): 2.3. 見出し

この結果を直接編集して正しい番号を振りなおして置換するのが行指向のgrep置換。

test.txt(3,1): 1. 見出し
test.txt(5,1): 1.1. 見出し ← gepの結果を直接編集して直す
test.txt(7,1): 1.2. 見出し
test.txt(10,1): 2. 見出し
test.txt(12,1): 2.1. 見出し
test.txt(14,1): 2.2. 見出し ← gepの結果を直接編集して直す

grepの結果で置換すると以下のように変更が反映される。

タイトル

1. 見出し
記事
1.1. 見出し ← 直った
記事
1.2. 見出し
記事

2. 見出し
記事
2.1. 見出し
記事
2.2. 見出し ← 直った

 

いつもどおりVBScriptとかFileSystemObjectとかがわからず、かなりはまった。

以下を修正。

  • 改行コードは元のファイル(の先頭行)に合わせるようにして、改行コードを変えないようにした。(改行コードが差分で出て困るし、そもそも改行コードは変えるべきでない)
  • 最初にgrep置換を実行するか確認を出した。(割り付けキーのミスタイプでいきなり置換されるのは危険なので)
  • 2017/6/3 バックアップフォルダの親フォルダが作成されるようにした。
  • 2017/6/8 UTF-8の場合にBOMを削除するようにした。
'###### 大域変数定義 ######
'置換したファイル数/行数
Dim repfcnt, replcnt
repfcnt = 0 '置換したファイル数
replcnt = 0 '置換した行数
'処理中のファイル名、行番号、文字コード
Dim file, lineno, charset
file = ""   '
lineno = 0
charset = GetCharset("SJIS") '文字コード
'ファイルオブジェクト/入出力オブジェクト
Dim fs, fi, fo
Set fs = CreateObject("Scripting.FileSystemObject")
Set fi = CreateObject("ADODB.Stream")
Set fo = CreateObject("ADODB.Stream")
'カレントディレクトリ、一時ディレクトリ
Dim curdir, tmpdir
Set curdir = fs.GetFolder(".")
Set tmpdir = fs.CreateFolder(fs.GetParentFolderName(curdir.path)+"\"+fs.GetTempName())
'正規表現オブジェクト
Dim re_grep, re_code, re_matches, re_match
'grep結果「ファイルパス(行番号,列番号): 置換内容」
Set re_grep = New RegExp
re_grep.Pattern = "^(.+?)\((\d+)(,\d+)?\): (.+)"
'文字コード文字コードセット:SJIS」など
Set re_code = New RegExp
re_code.Pattern = "^ +\(文字コードセット:(.+)\)"
'###### 主処理 ######
'最初に実行するか確認してから実行
rc = Editor.OkCancelBox("現在の編集内容でgrep置換を実行しますか?")
If rc = 1 Then
    GrepRepMain
End If
'###### サブルーチン ######
'grep置換本体
Sub GrepRepMain
    'grep結果に一致する行を置き換える
    allnum = Editor.GetLineCount(0)
    For i = 1 To allnum : Do
        '行を取得し、改行コードを削除する
        str = Chomp(Editor.GetLineStr(i))
        '複数のgrep結果がある場合に、空行を境とみなす
        If str = "" Then
            Finalize
            Exit Do
        End If
        '文字コード指定行の場合は文字コードを設定
        Set re_matches = re_code.Execute(str)
        If re_matches.Count > 0 Then
            Set re_match = re_matches(0)
            charset = GetCharset(re_match.submatches(0))
        End If
        'grep結果の行に一致した場合は置き換え
        Set re_matches = re_grep.Execute(str)
        If re_matches.Count > 0 Then
            'ファイルパス、行番号、対象行で行置換を呼び出し
            Set re_match = re_matches(0)
            GrepReplace re_match.submatches(0), CInt(re_match.submatches(1)), Chomp(re_match.submatches(3))
        End If
    Loop Until 1 : Next
    '残りの行の書き出し
    Finalize
    Editor.InfoMsg(""+CStr(repfcnt)+"ファイル、"+CStr(replcnt)+"行を置換しました。"+vbCrLf+tmpdir.path+"にバックアップがあります。")
End Sub
'対象行を置き換えるサブルーチン
Sub GrepReplace(t_file, t_lineno, t_str)
    '初回 or 前回のファイルと一致しない
    If t_file <> file Then
        '残りの書き込み
        Finalize
        '対象のファイルを設定、行番号の初期化
        file = t_file
        lineno = 0
        '書き込み用ファイルオブジェクトをオープン
        fo.Open
        fo.Type = 2 'テキスト
        fo.charset = charset '文字コード
        '読み込み対象ファイルをオープン
        fi.Open
        fi.Type = 2 'テキスト
        fi.charset = charset '文字コード
        fi.LineSeparator = 10 'LF
        fi.LoadFromFile file
        '1行読み込み、変換後の改行コードを設定
        If Right(fi.ReadText(-2), 1) = vbCr Then
            fo.LineSeparator = -1 'CR/LF
        Else
            fo.LineSeparator = 10 'LF
        End If
        fi.Position = 0
    End If
    ReplaceLine t_lineno, t_str
End Sub
'対象行を置き換える
'※t_linenoに0を指定することでファイルの最後まで読み込み/書き込み
Sub ReplaceLine(t_lineno, t_str)
    '1行ずつ読み込み、置換対象の行の場合は指定内容で置換
    Do While fi.EOS = False
        str = Chomp(fi.ReadText(-2))
        lineno = lineno + 1
        If lineno = t_lineno Then
            fo.WriteText t_str, 1
            replcnt = replcnt + 1
            Exit Do
        Else
            fo.WriteText str, 1
        End If
    Loop
End Sub
'残りの行の読み込み/書き込み、バックアップ取得、ファイル入替
Sub Finalize
    '対象ファイルがオープンしていなければ何もしない
    If file = "" Then
        Exit Sub
    End If
    '残りの行の読み込み/書き込み
    ReplaceLine 0, ""
    'UTF-8の場合はBOMを削除
    If fo.charset = "UTF-8" Then
        fo.Position = 0
        fo.Type = 1 'バイナリ
        fo.Position = 3
        data = fo.Read
        fo.Close
        fo.Open
        fo.Write(data)
    End If
    '一時ファイルに書き込みファイルクローズ
    ftmp = fs.GetTempName()
    fo.SaveToFile ftmp, 2
    fo.Close
    fi.Close
    'ファイル数のカウント
    repfcnt = repfcnt + 1
    '一時ディレクトリに同じパスでバックアップ用のファイル名を生成
    fbak = Replace(file, curdir.path, tmpdir.path)
    If fbak = file Then
        fbak = tmpdir.path + Replace(file, fs.GetDriveName, "")
    End If
    'バックアップ先のフォルダがなければ作成
    CreateParentFolder(fbak)
    'ファイルをバックアップして一時ファイルで置き換え
    fs.MoveFile file, fbak
    fs.MoveFile ftmp, file
    file = ""
End Sub
'親フォルダを再帰的に作成
Sub CreateParentFolder(path)
    parent = fs.GetParentFolderName(path)
    If Not fs.FolderExists(parent) Then
        CreateParentFolder(parent)
        fs.CreateFolder(parent)
    End If
End Sub
'###### 関数 ######
'改行コードを取り除く
Function Chomp(str)
    str = Replace(str, vbCr, "")
    Chomp = Replace(str, vbLf, "")
End Function
'文字コードの文字列を変換する
Function GetCharset(str)
    Select Case str
    Case "SJIS" GetCharset = "Shift_JIS"
    Case Else   GetCharset = str 'SJIS以外はとりあえず同じ文字列を返却
    End Select
End Function